#std758

Псевдонимы источников данных в запросах

1.

Псевдоним источника данных должен быть осмысленным и отражать назначение источника в текущем контексте.

Требования к псевдонимам близки к требованиям к #std454: именам переменных в коде.

  • образуйте псевдонимы от терминов предметной области;
  • пишите слитно, с заглавной буквы в каждом слове (например, ТоварыНаСкладах);
  • не начинайте псевдоним с подчеркивания;
  • не используйте псевдоним из одного символа.

Неправильно

ВЫБРАТЬ
    Таблица1.Ссылка КАК Товар,
    ЕстьNULL(Таблица2.КоличествоОстаток, 0) КАК Остаток
ИЗ
    Справочник.Номенклатура КАК Таблица1
    ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки КАК Таблица2
        ПО Таблица1.Ссылка = Таблица2.Номенклатура

Правильно

ВЫБРАТЬ
    ВсяНоменклатура.Ссылка КАК Товар,
    ЕстьNULL(ОстаткиНаСкладах.КоличествоОстаток, 0) КАК Остаток
ИЗ
    Справочник.Номенклатура КАК ВсяНоменклатура
    ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки КАК ОстаткиНаСкладах
        ПО ВсяНоменклатура.Ссылка = ОстаткиНаСкладах.Номенклатура

Не рекомендуется использовать в качестве псевдонимов имена классов метаданных (Справочник, Документ и т.д.), так как они обычно не описывают роль источника в конкретном запросе.

2.

Для универсальных механизмов, работающих с произвольными таблицами, допустимы универсальные псевдонимы.

Пример

"ВЫБРАТЬ
    |   Таблица.Наименование КАК Наименование,
    |   Таблица.Код КАК Код
    |ИЗ
    |   &Таблица КАК Таблица";

ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&Таблица", "Справочник." + ИмяСправочника);
Источник

https://its.1c.ru/db/v8std#content:758